Argthtjtr

I am trying to find the minimum values for all elements in a list of associations, below is an example

x = {<|"a"-> 4, "b"->9, "c"->15|>, <|"a"->21, "b"->11, "c"->1|>, <|"a"->12, "b"->3, "c"->21|>}

Required output for Min
{<|"a"-> 2, "b"->3, "c"->1|>}

Required output for Max
{<|"a"-> 21, "b"->11, "c"->15|>}

My attempt
for Max: MaximalBy[Values]@x
Result: {<|"a" -> 21, "b" -> 11, "c" -> 1|>}

for Min: MinimalBy[Values]@x
Result: {<|"a" -> 4, "b" -> 9, "c" -> 15|>}

Is there an elegant way to achieve this result?

How about

a = {

    <|"a" -> 4, "b" -> 9, "c" -> 15|>,

    <|"a" -> 21, "b" -> 11, "c" -> 1|>,

    <|"a" -> 12, "b" -> 3, "c" -> 21|>

};



Merge[a, Min]



(*<|"a" -> 4, "b" -> 3, "c" -> 1|>*)



Merge[a, Max]



(*<|"a" -> 21, "b" -> 11, "c" -> 21|>*)

EDIT

Improved, as per Kuba's suggestion.

Random`Private`MapThreadMin[x]

Random`Private`MapThreadMax[x]

<|"a" -> 4, "b" -> 3, "c" -> 1|>

<|"a" -> 21, "b" -> 11, "c" -> 21|>

You may use Query and MinMax.

With x as in OP.

Query[Transpose /* Map[MinMax]]@x

<|"a" -> {4, 21}, "b" -> {3, 11}, "c" -> {1, 21}|>

You can produce a more descriptive result with AssociationThread.

res = Query[Transpose /* Map[AssociationThread[{"Min", "Max"}, MinMax@#] &]]@x

<|"a" -> <|"Min" -> 4, "Max" -> 21|>, 

  "b" -> <|"Min" -> 3, "Max" -> 11|>, 

  "c" -> <|"Min" -> 1, "Max" -> 21|>|>

Which you can then access by Key with Association's syntax sugar.

res["a", "Max"]

21

Hope this helps.