Argthtjtr

I have two columns of data that overlap, looking something like this:

-------------------------

| Aardvarks  | Bears    |

| Bears      | Dogs     |

| Cats       | Giraffes |

| Giraffes   | Hippos   |

| Monkeys    | Rhinos   |

| Rhinos     | Zebras   |

-------------------------

Is there any way to align matching values between the two columns, whilst adding blank cells where differences exist, so that I get an end result like this:

-------------------------

| Aardvarks |           |

| Bears     | Bears     |

| Cats      |           |

|           | Dogs      |

| Giraffes  | Giraffes  |

|           | Hippos    |

| Monkeys   |           |

| Rhinos    | Rhinos    |

|           | Zebras    |

-------------------------

I've seen people ask similar questions on here, but all rely on the Column A having some sort of "complete" data and and Column B having incomplete data that needs sorting.

My issue is that both columns have duplicate and unique data (in the above example, Column A doesn't have all the animals).

Is there some way to align and arrange the columns to get this end result I'm looking for?

Sorry to waste people's time, but after doing even more online searching I found a solution to my own problem.

I found this site below that offers a VBA solution to the problem I was facing. The script worked perfectly for what I was hoping to achieve.

http://sites.madrocketscientist.com/jerrybeaucaires-excelassistant/text-functions/line-up-matches

The website looks to be down... thankfully I saved the useful VB last year

Option Explicit



Sub LineEmUp()

'Author:    Jerry Beaucaire

'Date:      7/5/2010

'Summary:   Line up a random number of columns so all matching

'           items are on the same rows

Dim LC  As Long

Dim Col As Long

Dim LR  As Long

Application.ScreenUpdating = False



'Spot last column of data

    LC = Cells(1, Columns.Count).End(xlToLeft).Column



'Add new key column  to collect unique values

    Cells(1, LC + 1) = "Key"

    For Col = 1 To LC

        Range(Cells(2, Col), Cells(Rows.Count, Col)).SpecialCells(xlConstants).Copy _

           Cells(Rows.Count, LC + 1).End(xlUp).Offset(1)

    Next Col



    Columns(LC + 1).AdvancedFilter Action:=xlFilterCopy, CopyToRange:=Cells(1, LC + 2), Unique:=True

    Columns(LC + 2).Sort Key1:=Cells(2, LC + 2), Order1:=xlAscending, Header:=xlYes



'Fill in new table headers w/formatting

    Range("A1", Cells(1, LC)).Copy Cells(1, LC + 3)



'Fill in new table values

    LR = Cells(Rows.Count, LC + 2).End(xlUp).Row

    With Range(Cells(2, LC + 3), Cells(LR, LC + 2 + LC))

        .FormulaR1C1 = "=IF(ISNUMBER(MATCH(RC" & LC + 2 & ",C[-" & LC + 2 _

                        & "],0)), RC" & LC + 2 & ", """")"

        .Value = .Value

    End With



'Cleanup/Erase old values

    Range("A1", Cells(1, LC + 2)).EntireColumn.Delete xlShiftToLeft

    Columns.Autofit

    Application.ScreenUpdating = True

End Sub