Argthtjtr

I need it to produce orders that are in Canada or Mexico, over $1,000, and in the month of July. The formula I am trying to use is:

=IF(OR(A2="Canada","Mexico", IF(C2>1000, "Ship by Air", IF(MONTH(B2=7, "Ship by Air", "Ship by Ground")))

I don't know how else to write it with all of that information.

OR needs each part to be its own Boolean expression:

OR(A2="Canada","Mexico"

Should be:

OR(A2="Canada",A2="Mexico")

OR

OR(A2={"Canada","Mexico"})

And

MONTH(B2

is missing the )

So:

=IF(OR(A2={"Canada","Mexico"}), IF(C2>1000, "Ship by Air", IF(MONTH(B2)=7, "Ship by Air", "Ship by Ground")))

Also you are missing the FALSE on the outer IF, which may be what you want, but I tend to add it so my formulas are more readable:

=IF(OR(A2={"Canada","Mexico"}), IF(C2>1000, "Ship by Air", IF(MONTH(B2)=7, "Ship by Air", "Ship by Ground")),FALSE)

But we can combine the inner two as the output is the same on the true:

=IF(OR(A2={"Canada","Mexico"}), IF(OR(C2>1000, MONTH(B2)=7), "Ship by Air", "Ship by Ground"),FALSE)

Edit: this will return Ship by Air if any of the following are TRUE:

• A2 equals "Canada" or "Mexico"


• C2 > 1000


• The Month of B2 is July

:

=IF(OR(A2={"Canada","Mexico"},C2>1000, MONTH(B2)=7), "Ship by Air", "Ship by Ground")

Edit2: this will return Ship by Air if All of the following are TRUE:

• A2 equals "Canada" or "Mexico"


• C2 > 1000


• The Month of B2 is July

:

=IF(AND(OR(A2={"Canada","Mexico"}),C2>1000, MONTH(B2)=7), "Ship by Air", "Ship by Ground")

You've got a good start; your formula is "pseudo-code" for what you want to accomplish. You just need to structure it for Excel.

The first problem is that the factors used by functions need to be enclosed in parentheses so Excel knows where they start and end. Your first OR doesn't have a close parenthesis; the same with the MONTH function.

The second problem is that the OR needs to contain a choice of complete conditions. Excel doesn't handle comparisons to a list, at least in a non-array format like you're using.

Also, the first IF doesn't contain a result for what to show if the OR is false, so you probably want to add that.

So the formula should look like:

=IF(OR(A2="Canada",A2="Mexico"), IF(C2>1000, "Ship by Air", IF(MONTH(B2)=7, "Ship by Air", "Ship by Ground")),"Not Canada or Mexico")

Count the brackets: You have five opening brackets and three closing brackets. But the counts have to match.

You can see the problem with correct indenting of the expression:

=IF(

    OR(

       A2="Canada","Mexico", 

       IF(

          C2>1000, "Ship by Air", 

          IF(

             MONTH(

                   B2=7, "Ship by Air", "Ship by Ground"

             )

          )

       )

// ---------------- Here your expression ends

    )    // missing

)        // missing

I marked the two missing closing brackets. Which expressions your want to close with ) depends on the logic you want to implement.