Argthtjtr

When I try this:

Framed@Graphics[{Text[

    Style["Text", FontSize -> 50, Bold, Black, Background -> Green, 

     FontFamily -> "Calibri"]]}]

I get a centered text with a large empty space around.

How can I align the text e.g. to left or how can I make the frame as large as the text is?

txt = Text[Framed[Style["Text", FontSize -> 150, Bold, Black, 

    FontFamily -> "Calibri"], Background -> Green, ContentPadding -> False]]; 

Graphics[txt, ImageSize -> Rasterize[txt, "RasterSize"]]

Alternatively, use the second argument of Text to specify the position:

txtb = Text[Framed[Style["Text", FontSize -> 150, Bold, Black, 

     FontFamily -> "Calibri"], Background -> Green, ContentPadding -> False], {0, 0}];

Graphics[txtb]

same picture

txt2 = Text[Framed[Style["TextTextTextTextTextnTextTextTextTextText", 

     FontSize -> 64, Bold, Black, FontFamily -> "Calibri", 

     LineSpacing -> {1, -10}], Background -> Green, ContentPadding -> False]];

Graphics[txt2, ImageSize -> Rasterize[txt2, "RasterSize"]]

Using the second approach:

txt2b = Text[Framed[Style["TextTextTextTextTextnTextTextTextTextText", 

     FontSize -> 64, Bold, Black, FontFamily -> "Calibri", 

     LineSpacing -> {1, -10}], Background -> Green, ContentPadding -> False], {0, 0}];

Graphics[txt2b]

same picture

You need to adjust ImageSize

Framed[Graphics[{Text[

    Style["Text", FontSize -> 150, Bold, Black, 

     FontFamily -> "Calibri"]]},  ImageSize -> {275, 105}], 

 Background -> Green]

Or

   Framed[Text[

  Style["Text", FontSize -> 150, Bold, Black, 

   FontFamily -> "Calibri"]], Alignment -> Center, 

 Background -> Green, FrameMargins -> 0, ContentPadding -> False, 

 ImageSize -> {277, 108}]

Framed[Text[

  Style["Red Fox jr", FontSize -> 150, Bold, Black, 

   FontFamily -> "Calibri"]], Alignment -> Center, 

 Background -> Green, FrameMargins -> 0, ContentPadding -> False]

I would use a slightly different approach which gives more flexibility.

Graphics[{Green, EdgeForm[Black], Rectangle[{0, 0}, {2, 1}], (*Green Background*)

 Inset[Style["Text", FontSize -> 150, Bold, Black,FontFamily -> "Calibri"],

 {0, 0}, {Left, Bottom}]}] (*position and alignment*)

Or some tilting

q = Pi/6;

Graphics[{Green, EdgeForm[Black], Rectangle[{0, 0}, {2, 1}], 

 Inset[Style["Text", FontSize -> 100, Bold, Black, FontFamily -> "Calibri"],

 {0.5, 0}, {-1,-0.5}, {Cos[q],Sin[q]}]}]

Look at Inset for more options.

For Text in a box

wordbox[text_, fontsize_, fontcolor_, font_, background_] := 

       Framed[ImageCrop@Rasterize@Style[text, FontSize -> fontsize, Bold, fontcolor, 

       FontFamily -> font, Background -> background],

       Background -> background, FrameMargins -> 0]



wordbox["Text", 100, Blue, "Calibri", Red]

wordbox["Texture", 100, Black, "Calibri", Green]